## Requirement

A common scenario in multinational companies is having to integrate different currency rates across transactional data.

Quite often sales data is stored regardless of the currency, so the currency code related to each sale is also stored in another column.

So, what we need to do is to integrate the whole daily historical exchange rates for every single currency used within the company.

Then a common approach is to convert through the ETL process all the sales data into one single currency usually USD obviously it can vary from one company to another. This is always a good practice to hold only one single currency in the DWH as it makes it much easier to apply all the business calculation rules.

Let’s assume that in our case we convert all the sales into USD.

However, large international companies have offices and firms all over the world and thus need financial dashboards and reports to be in their different offices’ local currencies.

So, one solution can be to create a dynamic currency conversion measure in Power BI so we can display the USD amount into any needed currencies.

Below I outline how we can solve this particular requirement in a few simple steps:

## Modeling

The fact CurrencyRate stores the daily historical exchange rates .
The dimension Currency links the currencies to the fact Currency Rates.
The dimension links the fact Currency Rate and the fact Internet Sales with the date attribute.

Note that if you want to hold and handle multiple currencies in your DWH you’ll need to duplicate the dim Currency, one used as a filter (with a direct link to the fact) and another as conversion calculator like in our scenario (with no link to the fact Sales)

## DAX Measure

```SalesAmountCurrency =

var _USDMeasure =sum(v_FactInternetSales[SalesAmount])
return
if(ISBLANK(_USDMeasure),blank(),
if(HASONEFILTER(v_DimCurrency[CurrencyName]),
-- the conversion calculation starts here
-- the above part is just used to handle null values
-- and slicer with multiple values allowed
var _sumx =sumx(
CROSSJOIN(
values(v_DimCurrency[CurrencyKey]),
values(DimDate[DateKey])
),
CALCULATE(
var _USDMeasurex =sum(v_FactInternetSales[SalesAmount])
return
Divide(_USDMeasurex,VALUES(FactCurrencyRate[AverageRate]))
)
)
return
_sumx,_USDMeasure
)
)

```

So this measure simply computes the conversion calculation row-by-row and as you will see in the result section the conversion will be calculated on the fly as we switch from one currency to another.

## Result

As you can see the sales amount gets automatically converted into the selected currency.

#### Make things look nicer

We can also use the above measure and concatenate the currency code with Sales Amout to automatically display the code currency with the sales amount

```SalesAmountCurrencyCode =

var _USDMeasure =sum(v_FactInternetSales[SalesAmount])
return
if(ISBLANK(_USDMeasure),blank(),
if(HASONEFILTER(v_DimCurrency[CurrencyName]),
var _sumx =sumx(
CROSSJOIN(
values(v_DimCurrency[CurrencyKey]),
values(DimDate[DateKey])
),
CALCULATE(
var _USDMeasurex =sum(v_FactInternetSales[SalesAmount])
return
Divide(_USDMeasurex,VALUES(FactCurrencyRate[AverageRate]))
)
)
return
if(ISBLANK(_sumx),
blank(),
concatenate(CONCATENATE(FIRSTNONBLANK(v_DimCurrency[CurrencyAlternateKey],1), " "),FORMAT( _sumx, "Standard")  )
),concatenate("USD ",FORMAT( _USDMeasure, "Standard") )
)
)

```

Note that the format type of this measure is now text.
Therefore, we can no longer simply reference this measure in another measure that would require advanced calculation such as ratio, YTD, projection and so on.
Also, if your users use Excel or want to export the PBI visual into Excel, it won’t work as the figures are in text format.

The sample data used in this post is from AdventureWorksDWH2014.

/

## DAX – TREATAS function – Book-to-Bill Ratio use case

Treatas is a powerful DAX function that applies the result of a table expression as filters to columns from an unrelated table.

In other words, treatas applies the filter context of a specific table to another unrelated table (no relationship in the model).

### Book to Bill ratio

A book-to-bill ratio is the ratio of orders received vs orders shipped and billed for a specific period, a month in our case.

The book-to-bill ratio reveals how quickly a business fulfils the demand for its products.

### How do we do this in DAX?

There’s couple of ways to achieve it:

• Bidirectional filter + changing the filter context: bad practice will literally kill the performance of your model
• Intersect + Lookup: was ok before the treatas function but turns to be much slower than treatas
• Role playing dimension + userelationship function: by far the fastest but you ned to use role playing dimensions
• Treatas: if like me you cannot use role playing dimensions for whatever reasons this is the best option

OK here is my model:

• Fact Order
• Order date dimension
• Ship date dimension

There isn’t any relationship between my two dimension and the granularity level of my fact table is the date (day).

We’ve received 2,457 orders between Jan 2019 and March 2019 and those 2,457 orders have been delivered between Jan 2019 and May 2018.

And here I filtered out only the orders received in January so among those orders only 369 have been shipped the same month which gives the following ratio: Ratio = Orders Received/Orders Shipped = 0.358

OK now remember there’s no relationship between my two date dimensions so how do we propagate the filter context of the Order Date to the Ship Date? This where Treatas comes in.

### Propagate the filter context to unrelated table with Treatas

Orders Shipped:
Only the orders shipped the same month as the received order are counted. This is done by propagating the filter context of the Order Date to the Ship Date.

```Orders SHipped (treatas) =
calculate(
sum('Fact Orders'[nb Orders]),
TREATAS(VALUES('Order Date'[YearMonthnumber]),'Ship Date'[YearMonthnumber])
)
```

Now we can compute the ratio applying the same logic.
Ratio (Book to Bill) = Total Orders Received / Total Orders Shipped

```book to bill ratio (treatas) =

DIVIDE(
calculate(
sum('Fact Orders'[nb Orders]),
TREATAS(VALUES('Order Date'[YearMonthnumber]),'Ship Date'[YearMonthnumber])

),calculate(sum('Fact Orders'[nb Orders]))
)
```

In my example, my model contains two unrelated Date tables.
When I apply a filter to Order Date[Year Month] “Jan2019” the same filter, “Jan2019” is applied to Shipped Date[Year Month] hence the two tables must use similar column types such as Date, Product, Location, Customer…

/

## Visualising Deviation From Average in Power BI

Note that throughout this article I will use the margin measure to illustrate the deviation from average application but the same pattern can be applied to any measures like Sales volume, Delivery time, Profit, etc…

Margin is a key metric to asses high level performance of a company.
But sometime we want to measure and compare specific shop or department or employee performance with the entire company over all performance and this where deviation from average metric comes to help.

### The requirement are as follows:

• Company overall margin over time (which is just the margin average)
• Employee margin over time
• Employee margin deviation from the company margin average over time
• Employee margin deviation vs Last Year Employee margin deviation

And the final result should look like this:

Now let’s define our measures:

### Margin  and Overall Margin calculation

#### Margin:

```Margin % = divide(([Total Revenue]-[Total COGS]),[Total COGS])
```

#### Overall Margin:

```All Margin =
if(
ISBLANK([Margin %]),
BLANK(),
calculate([Margin %],ALLEXCEPT('Fact','Date')
)```

Removes all context filters except filters that have been applied to the fact or date tables.

### Margin Deviation From Average measures

#### Margin Deviation From AVG:

```Margin Deviation =
var _AllMargin = calculate([Margin %],ALLEXCEPT('Fact','Date'))
Return
IF(ISBLANK([Margin %]),
BLANK(),
[Margin %] - _AllMargin
)```

#### Margin Deviation CY vs LY (Hidden):

```Margin Deviation CY vs LY (hidden)=
var _MarginDeviationLY = CALCULATE([Margin Deviation],SAMEPERIODLASTYEAR('Date'[Date])
)
var _MarginDeviationCYvsLY = [Margin Deviation] - _MarginDeviationLY
Return
IF(ISBLANK(_MarginDeviationLY),
BLANK(),
IF(_MarginDeviationCYvsLY>0,
1,
0
)
)```

#### Margin Deviation CY vs LY:

```Margin Deviation CY vs LY =
IF(ISBLANK([Margin Deviation CY vs LY (hidden)]),
BLANK(),
IF([Margin Deviation CY vs LY (hidden)>0,
UNICHAR(9650),
UNICHAR(9660)
)
)```

Unichar is a great function which returns the Unicode character referenced by the numeric value, we can draw really cool stuff with this function.
(UNICHAR(9650) Up-Arrow , UNICHAR(9660) Down-Arrow)

### Visualising everything together

Now let’s put together our measures into a matrix visual:

• Margin %: Margin by employee and by year
• All Margin: Yearly margin of the entire company
• Margin Deviation: This is simply the difference between the employee margin and the average margin of the entire company
• Margin Deviation CY vs LY: Current Year Margin Deviation versus Last Year Margin Deviation

How do we read this result:

Andrew Ma:
In 2013 the entire company margin AVG was 46.9% and Andrew margin was 35.46% hence below the AVG margin by -11.46%.
In 2014 the AVG margin is 74.32% and Andrew has now performed better than the AVG margin by 8.42%.
Note that Andrew has also increased his margin Deviation by nearly 20% (8.42–11.44) so he got a up arrow.

Tina Lassila:
In 2013 Tina realised a Margin% of 101.44% and she beat the AVG margin by 54.54%.
In 2014 Tina realised a Margin% of 116.67% which is a nice increase compared to 2013!
However, it turns out that the whole company performed better in 2014…
So if we look at Tina’s Margin Deviation compared to the last year we notice that she did not perform as good as in 2013 ans thus got a down arrow.

### A nicer visual

To get this visual we just need to keep the previous matrix above, remove the first two columns and then apply some conditional formatting using the Margin Deviation CY vs LY (hidden) measure.
And by looking at this visual we can clearly observe that Tina performance compare to the AVG Margin has decreased by around 10%.

In most cases the margin indicator is used to asses people, team or product performance.
However, by using the Margin only we’re missing out the overall trend of the company.  At first sight an increase of 15% seems great but once we realise that the overall increase was actually of 28% it doesn’t seem great anymore.

This is why margin deviation from average can provide really great insight from our data but using it alone could also be misleading as even if Tina Margin Deviation is not that good she’s still the best performer for the year of 2014.
So I think combining the Margin% and Margin Deviation from average measures together is always a good idea!

Here is the power BI Customer Profitability sample that I used for this article.

/